Scripting 运行时库参考（1）

日期：2005-6-26 10:51:12　作者：佚名　人气： 　 　 来源：Microsoft

Add 方法(Dictionary)

向 Dictionary 对象添加键和项目对。

object.Add key, item

参数

object

必选项。应为 Dictionary 对象的名称。

key

必选项。与添加的 item 相关的 key。

item

必选项。与添加的 key 相关的 item。

说明

如果 key 已经存在，则会出现错误。

下面例子举例说明如何使用 Add 方法：

Dim d                   '创建变量。
Set d = CreateObject("Scripting.Dictionary")
d.Add "a", "Athens"     '添加一些键和项目。
d.Add "b", "Belgrade"
d.Add "c", "Cairo"

请参阅

AddFolders 方法 | Exists 方法 | Items 方法 | Keys 方法 | Remove 方法 | RemoveAll 方法

应用于：Dictionary Object

AddFolders 方法(Folders)

向 Folders 集合添加新 Folder。

object. Add(folderName)

参数

object

必选项。应为 Folders 集合的名称。

folderName

必选项。要添加的新 Folder 名称。

说明

下面例子举例说明如何利用 Add 方法添加新文件夹：

Sub AddNewFolder(path, folderName)
  Dim fso, f, fc, nf
  Set fso = CreateObject("Scripting.FileSystemObject")
  Set f = fso.GetFolder(path)
  Set fc = f.SubFolders
  If folderName <> "" Then
    Set nf = fc.Add(folderName)
  Else
    Set nf = fc.Add("New Folder")
  End If
End Sub

如果 folderName 已经存在，则会出现错误。

请参阅

Add 方法(Folders)

应用于：Folders 集合

BuildPath 方法

向现有路径后添加名称。

object.BuildPath(path, name)

参数

object

必选项。应为 FileSystemObject 对象的名称。

path

必选项。要附加 name 的现有路径。可以是绝对或相对路径且无需指定现有文件夹。

name

必选项。要附加到现有 path 的名称。

说明

仅在必要时，BuildPath 方法在现有路径与该名称之间插入附加路径分隔符。

下面例子举例说明如何使用 BuildPath 方法：

Function GetBuildPath(path)
  Dim fso, newpath
  Set fso = CreateObject("Scripting.FileSystemObject")
  newpath = fso.BuildPath(path, "Sub Folder")
  GetBuildPath = newpath
End Function

请参阅

GetAbsolutePathName 方法 | GetBaseName 方法 | GetDriveName 方法 | GetExtensionName 方法 | GetFileName 方法 | GetParentFolderName 方法 | GetTempName 方法

应用于：FileSystemObject Object

Close 方法

关闭打开的 TextStream 文件。

object.Close

object 应为 TextStream 对象的名称。

说明

下面例子举例说明如何使用 Close 方法关闭打开的 TextStream 文件：

Sub CreateAFile
  Dim fso, MyFile
  Set fso = CreateObject("Scripting.FileSystemObject")
  Set MyFile = fso.CreateTextFile("c:\testfile.txt", True)
  MyFile.WriteLine("这是一个测试。")
  MyFile.Close
End Sub

请参阅

Read 方法 | ReadAll 方法 | ReadLine 方法 | Skip 方法 | SkipLine 方法 | Write 方法 | WriteLine 方法 | WriteBlankLines 方法

应用于：TextStream 对象

Copy 方法

将指定的文件或文件夹从某位置复制到另一位置。

object.Copy destination[, overwrite]

参数

object

必选项。应为 File 或 Folder 对象的名称。

destination

必选项。复制文件或文件夹的目标位置。不允许使用通配符。

overwrite

可选项。Boolean 值。如果覆盖现有文件或文件夹，则 Boolean 值为 True（默认）；否则为 False。

说明

对 File 或 Folder 应用 Copy 方法的结果与使用 FileSystemObject.CopyFile 或 FileSystemObject.CopyFolder 执行的操作完全相同。在 FileSystemObject.CopyFile 或 FileSystemObject.CopyFolder 中，使用 object 引用文件或文件夹，并将文件或文件夹作为参数传递给 FileSystemObject.CopyFile 或 FileSystemObject.CopyFolder。然而，应该注意的是 FileSystemObject.CopyFile 或 FileSystemObject.CopyFolder 方法可以复制多个文件或文件夹。

下列示例显示了 Copy 方法的使用：

Dim fso, MyFile
Set fso = CreateObject("Scripting.FileSystemObject")
Set MyFile = fso.CreateTextFile("c:\testfile.txt", True)
MyFile.WriteLine("这是一个测试")
MyFile.Close
Set MyFile = fso.GetFile("c:\testfile.txt")
MyFile.Copy ("c:\windows\desktop\test2.txt")

请参阅

CopyFile 方法 | CopyFolder 方法 | Delete 方法 | Move 方法 | OpenAsTextStream 方法

应用于：File 对象 | Folder 对象

CopyFile 方法

将一个或多个文件从某位置复制到另一位置。

object.CopyFile source, destination[, overwrite]

参数

object

必选项。应为 FileSystemObject 对象的名称。

source

必选项。表示指定文件的字符串。要复制一个或多个文件时，文件名中可以有通配符。

destination

必选项。表示目标位置的字符串，从 source 复制文件到该位置。不允许用通配符。

overwrite

可选项。Boolean 值表明是否覆盖现有文件。如果是 True，则覆盖文件；如果是 False，则不覆盖现有文件。默认值是 True。要注意，无论 overwrite 设置为何值，只要设置 destination 为只读属性，CopyFile 操作就无法完成。

说明

仅能在 source 参数的路径最后一个组成部分中使用通配符。例如，可以使用：

FileSystemObject.CopyFile "c:\mydocuments\letters\*.doc", "c:\tempfolder\"

但是，不能使用：

FileSystemObject.CopyFile "c:\mydocuments\*\R1???97.xls", "c:\tempfolder"

如果 source 包含通配符或 destination 以路径分隔符 (\) 结束，则假定 destination 是现有文件夹，复制匹配文件到该文件夹。否则，假定 destination 为要创建的文件。在任一种情况下，复制单个文件时，会出现以下三种情况。

• 如果 destination 不存在，则复制 source。这是通常会发生的情况。
• 如果 destination 是已经存在的文件，当 overwrite 为 False 时会出现错误。否则，复制 source 覆盖现有文件。
• 如果 destination 是目录，则会出现错误。

如果 source 使用通配符，但并没有相匹配的文件时，则会出现错误。CopyFile 方法在遇到出现的第一个错误时停止。该方法不会撤消错误发生前所作的任何更改。

请参阅

Copy 方法 | CopyFolder 方法 | CreateTextFile 方法 | DeleteFile 方法 | MoveFile 方法

应用于：FileSystemObject 对象

CopyFolder 方法

将文件夹从某位置递归复制到另一位置。

object.CopyFolder source, destination[, overwrite]

参数

object

必选项。应为 FileSystemObject 对象的名称。

source

必选项。表示指定文件夹的字符串。要复制一个或多个文件夹时，可使用通配符。

destination

必选项。表示目标位置的字符串，复制 source 文件夹或子文件夹到该位置。不允许用通配符。

overwrite

可选项。Boolean 值表明是否覆盖现有文件夹。如果为 True，则覆盖文件；如果为 False，则不覆盖文件。默认值是 True。

说明

仅能在 source 参数的路径最后一个组成部分中使用通配符。例如，可以使用：

FileSystemObject.CopyFolder "c:\mydocuments\letters\*", "c:\tempfolder\"

但是，不可以使用：

FileSystemObject.CopyFolder "c:\mydocuments\*\*", "c:\tempfolder\"

如果 source 包含通配符或 destination 以路径分隔符 (\) 结束，则假定 destination 是现有文件夹，在该文件夹中复制匹配文件夹或子文件夹。否则，假定 destination 是要创建的文件夹。在任一种情况下，复制单个文件夹时，会发生如下四种情况。

• 如果 destination 不存在，则复制 source 文件夹和其所有内容。这是通常会发生的情况。
• 如果 destination 是已经存在的文件，则出现错误。
• 如果 destination 是目录，则复制文件夹和其中的所有内容。如果在 destination 已经存在 source 包含的文件，且 overwrite 为 False，则会出现错误。否则，复制该文件覆盖现有文件。
• 如果 destination 是只读目录，在向该目录复制现有只读文件，且 overwrite 为 False 时，就会出现错误。

如果 source 使用通配符，但没有匹配文件时，也会出现错误。

CopyFolder 方法在遇到出现的第一个错误时停止。该方法不会撤消错误发生前所作的任何更改。

请参阅

CopyFile 方法 | Copy 方法 | CreateFolder 方法 | DeleteFolder 方法 | MoveFolder 方法

应用于：FileSystemObject 对象

CreateFolder 方法

创建文件夹。

object.CreateFolder(foldername)

参数

object

必选项。应为 FileSystemObject 对象的名称。

foldername

必选项。字符串表达式，指明要创建的文件夹。

说明

如果指定的文件夹已经存在，则会出现错误。

下面例子举例说明如何使用 CreateFolder 方法：

 Function CreateFolderDemo 
  Dim fso, f
  Set fso = CreateObject("Scripting.FileSystemObject")
  Set f = fso.CreateFolder("c:\New Folder")
  CreateFolderDemo = f.Path
End Function

请参阅

CopyFolder 方法 | DeleteFolder 方法 | MoveFolder 方法

应用于：FileSystemObject 对象

下一篇：Scripting 运行时库参考