Scripting 运行时库参考（8）

日期：2005-6-26 11:06:27　作者：佚名　人气： 　 　 来源：Microsoft

FileSystem 属性

返回指定的驱动器使用的文件系统的类型。

object.FileSystem

object 应为 Drive 对象的名称。

说明

可用的返回类型包括 FAT、NTFS 和 CDFS。

以下代码举例说明如何使用 FileSystem 属性：

 Function ShowFileSystemType(drvspec)
    Dim fso,d, s
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set d = fso. GetDrive(drvspec)
    ShowFileSystemType = d.FileSystem
End Function

请参阅

AvailableSpace 属性 | DriveLetter 属性 | DriveType 属性 | FileSystemObject 对象 | FreeSpace 属性 | IsReady 属性 | Path 属性 | RootFolder 属性 | SerialNumber 属性 | ShareName 属性 | TotalSize 属性 | VolumeName 属性

应用于：Drive 对象

FreeSpace 属性

返回指定的驱动器或网络共享对于用户的可用空间大小。只读。

object.FreeSpace

object 应为 Drive 对象的名称。

说明

FreeSpace 属性与 AvailableSpace 属性返回的值基本相同。对于支持限额的计算机系统来说，这两个属性返回的值有所差异。

以下代码举例说明如何使用 FreeSpace 属性：

Function ShowFreeSpace(drvPath)
    Dim fso, d, s
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set d = fso.GetDrive(fso.GetDriveName(drvPath))
    s = "驱动器 " & UCase(drvPath) & " - " 
    s = s & d.VolumeName  &"<BR>"
    s = s & "可用空间：" & FormatNumber(d.FreeSpace/1024, 0) 
    s = s & "KB"
ShowFreeSpace = s
End Function

请参阅

AvailableSpace 属性 | DriveLetter 属性 | DriveType 属性 | FileSystem 属性 | IsReady 属性 | Path 属性 | RootFolder 属性 | SerialNumber 属性 | ShareName 属性 | TotalSize 属性 | VolumeName 属性

应用于：Drive 对象

IsReady 属性

如果指定的驱动器就绪，返回 True；否则返回 False。

object.IsReady

object 应为 Drive 对象的名称。

说明

对于可移动媒体驱动器和 CD-ROM 驱动器，仅当插入相应的媒体并准备接受访问时，IsReady 返回 True。

以下代码举例说明如何使用 IsReady 属性：

Function ShowDriveInfo(drvpath)
    Dim fso, d, s, t
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set d = fso.GetDrive(drvpath)
    Select Case d.DriveType
        Case 0: t = "未知"
        Case 1: t = "可移动"
        Case 2: t = "固定"
        Case 3: t = "网络"
        Case 4: t = "CD-ROM"
        Case 5: t = "RAM 磁盘"
    End Select
    s = "驱动器 " & d.DriveLetter & ": - " & t
    If d.IsReady Then 
        s = s & "<BR>" & "驱动器已就绪。"
    Else
        s = s & "<BR>"  & "驱动器未就绪。"
    End If
ShowDriveInfo = s
End Function

请参阅

AvailableSpace 属性 | DriveLetter 属性 | DriveType 属性 | FileSystem 属性 | FreeSpace 属性 | Path 属性 | RootFolder 属性 | SerialNumber 属性 | ShareName 属性 | TotalSize 属性 | VolumeName 属性

应用于：Drive 对象

IsRootFolder 属性

如果指定的文件夹是根文件夹，返回 True；否则返回 False。

object.IsRootFolder

object 应为 Folder 对象的名称。

说明

以下代码举例说明如何使用 IsRootFolder 属性：

Function DisplayLevelDepth(pathspec)
Dim fso, f, n 
Set fso = CreateObject("Scripting.FileSystemObject")
Set f = fso.GetFolder(pathspec)
    If f.IsRootFolder Then
        DisplayLevelDepth ="指定的文件夹是根文件夹。"
    Else
        Do Until f.IsRootFolder
            Set f = f.ParentFolder
            n = n + 1
        Loop
       DisplayLevelDepth ="指定的文件夹是嵌套级为 " & n & " 的文件夹。"
    End If
End Function

请参阅

Attributes 属性 | DateCreated 属性 | DateLastAccessed 属性 | DateLastModified 属性 | Drive 属性 | Files 属性 | Name 属性 | ParentFolder 属性 | Path 属性 | ShortName 属性 | ShortPath 属性 | Size 属性 | SubFolders 属性 | Type 属性

应用于：Folder 对象

Item 属性

设置或返回 Dictionary 对象中指定的 key 对应的 item，或返回集合中基于指定的 key 的 item。可读写。

object.Item(key) [= newitem]

参数

object

必选项。应为集合或 Dictionary 对象的名称。

key

必选项。与检索或添加的 item 相关联的 key。

newitem

可选项。仅用于 Dictionary 对象，不能应用于集合。如果提供此参数，则 newitem 是与指定的 key 相关联的项目的新值。

说明

如果更改 item 时未找到 key，则使用指定的 newitem 创建一个新的 key。如果试图返回一个已有项目时未找到 key，则创建一个新的 key 并且它对应的项目为空值。

下面例子举例说明如何使用 Item 属性：

Function ItemDemo
  Dim d                   '创建变量.
  Set d = CreateObject("Scripting.Dictionary")
  d.Add "a", "Athens"     '添加键和项目对.
  d.Add "b", "Belgrade"
  d.Add "c", "Cairo"
  ItemDemo = d.Item("c")  '得到项目.         
End Function

请参阅

CompareMode 属性 | Count 属性 | Key 属性

应用于：Dictionary 对象 | Drives 集合 | Files 集合 | Folders 集合 | Matches 集合

Key 属性

在 Dictionary 对象中设置 key。

object.Key(key) = newkey

参数

object

必选项。通常是 Dictionary 对象的名称。

Key

必选项。要改变的 Key 值。

Newkey

必选项。代替指定 key 值的新值。

说明

如果在更改 key 值时未找到 key，则出现运行时错误。

下面例子举例说明如何使用 Key 属性：

Function DicDemo
  Dim d                   '创建变量。
  Set d = CreateObject("Scripting.Dictionary")
  d.Add "a", "Athens"     '添加键和项目对。
  d.Add "b", "Belgrade"
  d.Add "c", "Cairo"
  d.Key("c") = "d"        '将"c"的键设置为"d"。
  DicDemo = d.Item("d")   '返回相关项目。
End Function

请参阅

CompareMode 属性 | Count 属性 | Item 属性

应用于：Dictionary 对象

Line 属性

只读属性，返回 TextStream 文件中的当前行号。

object.Line

object 通常是 TextStream 对象的名称。

说明

文件刚刚打开并在写入任何信息前，Line 等于 1。

下面例子举例说明如何使用 Line 属性：

Function GetLine
  Const ForReading = 1, ForWriting = 2
  Dim fso, f, ra
  Set fso = CreateObject("Scripting.FileSystemObject")
  Set f = fso.OpenTextFile("c:\testfile.txt", ForWriting, True)
  f.Write "世界你好!" & vbCrLf & "VB脚本很有趣!" & vbCrLf
  Set f = fso.OpenTextFile("c:\testfile.txt", ForReading)
  ra =  f.ReadAll
  GetLine = f.Line   
End Function

请参阅

AtEndOfStream 属性 | AtEndOfLine 属性 | Column 属性

应用于：TextStream 对象

Name 属性

设置或返回指定的文件或文件夹的名称。可读写。

object.Name [= newname]

参数

object

必选项。应为 File 或 Folder 对象的名称。

newname

可选项。如果提供此参数，则指定的 object 名称更新为 newname。

说明

以下代码举例说明如何使用 Name 属性：

Function ShowFileAccessInfo(filespec)
    Dim fso, f, s
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set f = fso.GetFile(filespec)
    s = f.Name & " 位于驱动器 " & UCase(f.Drive) & "<BR>"
    s = s & "创建时间：" & f.DateCreated & "<BR>"
    s = s & "上次访问时间：" & f.DateLastAccessed & "<BR>"
    s = s & "上次修改时间：" & f.DateLastModified  
ShowFileAccessInfo = s
End Function

请参阅

Attributes 属性 | DateCreated 属性 | DateLastAccessed 属性 | DateLastModified 属性 | Drive 属性 | Files 属性 | IsRootFolder 属性 | ParentFolder 属性 | Path 属性 | ShortName 属性 | ShortPath 属性 | Size 属性 | SubFolders 属性 | Type 属性

应用于：File 对象 | Folder 对象

下一篇：Scripting 运行时库参考（7）